Create a custom Apex class to send case record context

global with sharing class PassageRetrievalWithRecordContext {

    @InvocableMethod(label='Coveo Passage Retrieval API in a Prompt Template'
    description='Retrieve Passages from Coveo PRAPI to use in a Prompt Template')
    global static List<Response> retrievePassages(List<Request> requests) {
        List<Response> responses = new List<Response>();

        // Convert the incoming requests to the format expected by the Coveo Passage Retrieval API class.
        List<CoveoAgentforce.InvocablePassageRetrievalFlex.Request> coveoRequests = new List<CoveoAgentforce.InvocablePassageRetrievalFlex.Request>();
        for(Request request: requests) {
            Case myExampleCaseRecord = request.caseRecord; 

            CoveoAgentforce.InvocablePassageRetrievalFlex.Request coveoRequest = new CoveoAgentforce.InvocablePassageRetrievalFlex.Request();
            coveoRequest.userInput = myExampleCaseRecord.Subject; 
            coveoRequest.prapiConfig = request.prapiConfig; 
            coveoRequest.additionalContext = JSON.serialize(new Map<String,String>{'Case_Description' => myExampleCaseRecord.Description}); 
            coveoRequests.add(coveoRequest);
        }

        List<CoveoAgentforce.InvocablePassageRetrievalFlex.Response> coveoResponses = CoveoAgentforce.InvocablePassageRetrievalFlex.retrievePassages(coveoRequests); 
        for(CoveoAgentforce.InvocablePassageRetrievalFlex.Response coveoResponse: coveoResponses) {
            Response response = new Response();
            response.Prompt = coveoResponse.Prompt; 
            responses.add(response);
        }
        return responses;
    }

    global class Request { 
        @InvocableVariable(required=true label='Case record' description='The case to retrieve passages for')
        global Case caseRecord;
        @InvocableVariable(required=true label='User Query' description='The user input to retrieve passages for')
        global String userInput;
        @InvocableVariable(required=true label='Name of the Passage Retrieval configuration'
        description='The Name of the custom metadata type record to apply a Passage Retrieval configuration,
        can either be the ID "m00000000000001" or the Developer Name "My_PRAPI_Config" or the fully qualified name "MyNamespace__My_PRAPI_Config"')
        global String prapiConfig;
    }

    global class Response { 
        @InvocableVariable(label='Passages response' description='The passages retrieved from Coveo Passage Retrieval API')
        global String Prompt; 
    }
}